[PLUGIN] Round Weapon Selector

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

public plugin_init()
{
    register_plugin("Round Weapon Selector", "1.1", "Unguru")
    RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
}

public player_spawn(id)
{
    if(!is_user_alive(id))
        return

    set_task(0.5, "show_weapon_menu", id)
}

public show_weapon_menu(id)
{
    if(!is_user_alive(id))
        return

    new menu = menu_create("\yAlege armele pentru runda:", "menu_handler")

    menu_additem(menu, "M4A1 + Deagle + Grenazi", "1")
    menu_additem(menu, "AWP + Deagle + Grenazi", "2")
    menu_additem(menu, "AK47 + Deagle + Grenazi", "3")

    menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER)
    menu_display(id, menu)
}

public menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }

    new data[6], name[64]
    new access, callback
    menu_item_getinfo(menu, item, access, data, charsmax(data), name, charsmax(name), callback)

    new key = str_to_num(data)

    strip_user_weapons(id)
    give_item(id, "weapon_knife")

    give_item(id, "weapon_deagle")
    cs_set_user_bpammo(id, CSW_DEAGLE, 35)

    give_item(id, "weapon_hegrenade")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_smokegrenade")

    switch(key)
    {
        case 1:
        {
            give_item(id, "weapon_m4a1")
            cs_set_user_bpammo(id, CSW_M4A1, 90)
        }
        case 2:
        {
            give_item(id, "weapon_awp")
            cs_set_user_bpammo(id, CSW_AWP, 30)
        }
        case 3:
        {
            give_item(id, "weapon_ak47")
            cs_set_user_bpammo(id, CSW_AK47, 90)
        }
    }

    menu_destroy(menu)
    return PLUGIN_HANDLED
}